load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_csm.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/csm/gsn_code.ncl"
load "$NCARG_ROOT/lib/ncarg/nclscripts/wrf/WRFUserARW.ncl"

begin

; for use of high resolution map database, execute
; 'setenv NCARG_RANGS /network/rit/lab/atm419lab/zhou/rangs' (on snow)
; 'setenv NCARG_RANGS /atm419lab/zhou/rangs' (on ash, reed)
; before running the script

c="./wind.txt"
cmap=asciiread(c,(/68,3/),"float")
cmap=cmap/255

center=asciiread("../../DATA_FAILURE_END/latlon_failure_end.txt",(/82,2/),"float")
;print(center(:,1))
tinfo=asciiread("../../DATA_FAILURE_END/time_failure_end.txt",(/82,2/),"integer")
yyyymmddhh=tinfo(:,1)
;print(yyyymmddhh)
name=asciiread("../../DATA_FAILURE_END/name_failure.txt",(/82/),"string")
;print(name)

dcase=dimsizes(yyyymmddhh)
U_comp=new((/dcase,161,161/),"float")
V_comp=new((/dcase,161,161/),"float")
Z_comp=new((/dcase,161,161/),"float")

do case=0,dcase-1,1

print("working on "+yyyymmddhh(case)+" -- "+name(case))

data=addfile("../../DATA_FAILURE_END/"+yyyymmddhh(case)+"_UV.grib","r")
;names=getfilevarnames(data)
;print(names)

U:=data->U_GDS0_ISBL
U!0="lev"
U!1="lat"
U!2="lon"

V:=data->V_GDS0_ISBL
V!0="lev"
V!1="lat"
V!2="lon"

Z:=data->Z_GDS0_ISBL
;printVarSummary(Z)
Z!0="lev"
Z!1="lat"
Z!2="lon"

;print(U&lev) ; levs are 200, 500, 850
;print(U&lat)

lat=U&lat
lon=U&lon
centlat_ind=ind_nearest_coord(center(case,0),lat,0)
centlon_ind=ind_nearest_coord(center(case,1),lon,0)
centlat=lat(centlat_ind)
centlon=lon(centlon_ind)

U850=U(2,:,:)
V850=V(2,:,:)
MAG=sqrt(U850^2+V850^2)
Z850=Z(2,:,:)/9.8/10.0

copy_VarMeta(U(0,:,:),U850)
copy_VarMeta(U(0,:,:),V850)
copy_VarMeta(U(0,:,:),MAG)
copy_VarMeta(Z(0,:,:),Z850)

pi=4.0*atan(1.0)
mlist=(/2,3,4,2,5,6,7,2,8,9,2/)
dm=dimsizes(mlist)

U850_1deg=U850(::4,::4)
V850_1deg=V850(::4,::4)
Z850_1deg=Z850(::4,::4)
;printVarSummary(U850_1deg)
;print(U850_1deg&lon)
lat_1deg=U850_1deg&lat
lon_1deg=U850_1deg&lon
dlat_1deg=dimsizes(lat_1deg)
dlon_1deg=dimsizes(lon_1deg)

U850_1deg_smthx=U850_1deg
V850_1deg_smthx=V850_1deg
Z850_1deg_smthx=Z850_1deg

do m=0,dm-1,1
  ;print("max u ="+max(U850_1deg_smthx)+"min u ="+min(U850_1deg_smthx))
  K=0.5*(1.0-cos(2.0*pi/mlist(m)))^(-1.0)

  U850_1deg_smthx_inter=U850_1deg_smthx
  V850_1deg_smthx_inter=V850_1deg_smthx
  Z850_1deg_smthx_inter=Z850_1deg_smthx

    do i=1,dlon_1deg-2,1

      U850_1deg_smthx(:,i)=U850_1deg_smthx_inter(:,i)+K*(U850_1deg_smthx_inter(:,i-1)+U850_1deg_smthx_inter(:,i+1)-2.0*U850_1deg_smthx_inter(:,i))
      V850_1deg_smthx(:,i)=V850_1deg_smthx_inter(:,i)+K*(V850_1deg_smthx_inter(:,i-1)+V850_1deg_smthx_inter(:,i+1)-2.0*V850_1deg_smthx_inter(:,i))
      Z850_1deg_smthx(:,i)=Z850_1deg_smthx_inter(:,i)+K*(Z850_1deg_smthx_inter(:,i-1)+Z850_1deg_smthx_inter(:,i+1)-2.0*Z850_1deg_smthx_inter(:,i))

    end do

end do

U850_1deg_smthy=U850_1deg_smthx
V850_1deg_smthy=V850_1deg_smthx
Z850_1deg_smthy=Z850_1deg_smthx

do m=0,dm-1,1
  ;print("max u ="+max(U850_1deg_smthy)+"min u ="+min(U850_1deg_smthy))
  K=0.5*(1.0-cos(2.0*pi/mlist(m)))^(-1)

  U850_1deg_smthy_inter=U850_1deg_smthy
  V850_1deg_smthy_inter=V850_1deg_smthy
  Z850_1deg_smthy_inter=Z850_1deg_smthy

    do j=1,dlat_1deg-2,1

      U850_1deg_smthy(j,:)=U850_1deg_smthy_inter(j,:)+K*(U850_1deg_smthy_inter(j-1,:)+U850_1deg_smthy_inter(j+1,:)-2.0*U850_1deg_smthy_inter(j,:))
      V850_1deg_smthy(j,:)=V850_1deg_smthy_inter(j,:)+K*(V850_1deg_smthy_inter(j-1,:)+V850_1deg_smthy_inter(j+1,:)-2.0*V850_1deg_smthy_inter(j,:))
      Z850_1deg_smthy(j,:)=Z850_1deg_smthy_inter(j,:)+K*(Z850_1deg_smthy_inter(j-1,:)+Z850_1deg_smthy_inter(j+1,:)-2.0*Z850_1deg_smthy_inter(j,:))

    end do

end do

U850_1deg_smth=U850_1deg_smthy
V850_1deg_smth=V850_1deg_smthy
Z850_1deg_smth=Z850_1deg_smthy

;print("max u ="+max(U850_1deg_smth)+"min u ="+min(U850_1deg_smth))
;print("max v ="+max(V850_1deg_smth)+"min v ="+min(V850_1deg_smth))
;print("max z ="+max(Z850_1deg_smth)+"min z ="+min(Z850_1deg_smth))

U850_smth=linint2(lon_1deg,lat_1deg(::-1),U850_1deg_smth,True,lon,lat(::-1),0) ;lat should be increasing
V850_smth=linint2(lon_1deg,lat_1deg(::-1),V850_1deg_smth,True,lon,lat(::-1),0) ;as long as two sets of lat are aligned,
Z850_smth=linint2(lon_1deg,lat_1deg(::-1),Z850_1deg_smth,True,lon,lat(::-1),0) ;original data sequence doesn't matter

;print(num(ismissing(U850_smth)))
;print(num(ismissing(V850_smth)))
;print(num(ismissing(Z850_smth)))
;printVarSummary(U850_smth)

copy_VarMeta(U850,U850_smth) ;otherwise, lat will be flipped
copy_VarMeta(V850,V850_smth)
copy_VarMeta(Z850,Z850_smth)

U850_dev=U850-U850_smth
V850_dev=V850-V850_smth
Z850_dev=Z850-Z850_smth

copy_VarMeta(U850,U850_dev) 
copy_VarMeta(V850,V850_dev)
copy_VarMeta(Z850,Z850_dev)

;print("max Udev = "+max(U850_dev)+" min Udev = "+min(U850_dev))

rn=31 ;radius of interpolation domain, set bigger than needed (7.5 deg instead of 5 deg)
tn=72 
dr=0.25 ; deg lat/lon
dtheta=5 ;deg
theta=ispan(0,360-1,dtheta)

lon_cyl2d=new((/rn,tn/),float)
lat_cyl2d=new((/rn,tn/),float)

do r=0,rn-1,1

  lon_cyl2d(r,:)=lon(centlon_ind)+r*dr*cos(theta*pi/180)
  lat_cyl2d(r,:)=lat(centlat_ind)+r*dr*sin(theta*pi/180)

end do

lon_cyl1d=ndtooned(lon_cyl2d)
lat_cyl1d=ndtooned(lat_cyl2d)

;print(lon_cyl1d)

U850_dev_cyl1d=linint2_points(lon,lat(::-1),U850_dev(::-1,:),True,lon_cyl1d,lat_cyl1d,0) ;need to reverse original data 
V850_dev_cyl1d=linint2_points(lon,lat(::-1),V850_dev(::-1,:),True,lon_cyl1d,lat_cyl1d,0) ;corresponding to lat array
Z850_dev_cyl1d=linint2_points(lon,lat(::-1),Z850_dev(::-1,:),True,lon_cyl1d,lat_cyl1d,0)

U850_dev_cyl2d=reshape(U850_dev_cyl1d,(/rn,tn/))
V850_dev_cyl2d=reshape(V850_dev_cyl1d,(/rn,tn/))
Z850_dev_cyl2d=reshape(Z850_dev_cyl1d,(/rn,tn/))

;print("max Udev = "+max(U850_dev)+" min Udev = "+min(U850_dev))
;print("max Udev.interp = "+max(U850_dev_cyl1d)+" min Udev.interp = "+min(U850_dev_cyl1d))

r0=21 ;radius of filtering domain (5 deg)
l=r0/5.0 ;parameter controling filtering shape

U850_vortex_cyl2d=U850_dev_cyl2d
V850_vortex_cyl2d=V850_dev_cyl2d
Z850_vortex_cyl2d=Z850_dev_cyl2d

;print("max Uvortex = "+max(U850_vortex_cyl2d)+" min Uvortex = "+min(U850_vortex_cyl2d))

do r=0,rn-1,1
  
  if (r.le.r0) then

    E=(exp(-((r0-r)^2/l^2))-exp(-((r0)^2/l^2)))/(1.0-exp(-((r0)^2/l^2)))
    ;print("E = "+E)
    U850_vortex_cyl2d(r,:)=U850_dev_cyl2d(r,:)-U850_dev_cyl2d(r0,:)*E-avg(U850_dev_cyl2d(r0,:))*(1-E)
    V850_vortex_cyl2d(r,:)=V850_dev_cyl2d(r,:)-V850_dev_cyl2d(r0,:)*E-avg(V850_dev_cyl2d(r0,:))*(1-E)
    Z850_vortex_cyl2d(r,:)=Z850_dev_cyl2d(r,:)-Z850_dev_cyl2d(r0,:)*E-avg(Z850_dev_cyl2d(r0,:))*(1-E)

  else

    U850_vortex_cyl2d(r,:)=0
    V850_vortex_cyl2d(r,:)=0
    Z850_vortex_cyl2d(r,:)=0

  end if

end do

;print("max Uvortex = "+max(U850_vortex_cyl2d)+" min Uvortex = "+min(U850_vortex_cyl2d))
;small discrepancy should be a result of TC location difference

lon_sub=lon(centlon_ind-20:centlon_ind+20)
lat_sub=lat(centlat_ind+20:centlat_ind-20)

U850_vortex_sub=transpose(dsgrid2(lon_cyl1d,lat_cyl1d,ndtooned(U850_vortex_cyl2d),lon_sub,lat_sub)) ;dsgrid returns dx*dy array
V850_vortex_sub=transpose(dsgrid2(lon_cyl1d,lat_cyl1d,ndtooned(V850_vortex_cyl2d),lon_sub,lat_sub)) ;instead of dy*dx !!!!!!!!!
Z850_vortex_sub=transpose(dsgrid2(lon_cyl1d,lat_cyl1d,ndtooned(Z850_vortex_cyl2d),lon_sub,lat_sub))

;print("max Uvortex_sub = "+max(U850_vortex_sub)+" min Uvortex_sub = "+min(U850_vortex_sub))
;printVarSummary(U850_vortex_sub)

copy_VarMeta(U850(centlat_ind+20:centlat_ind-20,centlon_ind-20:centlon_ind+20),U850_vortex_sub)
copy_VarMeta(V850(centlat_ind+20:centlat_ind-20,centlon_ind-20:centlon_ind+20),V850_vortex_sub)
copy_VarMeta(Z850(centlat_ind+20:centlat_ind-20,centlon_ind-20:centlon_ind+20),Z850_vortex_sub)

;printVarSummary(U850_vortex_sub)

U850_vortex_rm=U850
V850_vortex_rm=V850
Z850_vortex_rm=Z850

;print("max Uvortex_rm = "+max(U850_vortex_rm)+" min Uvortex_rm = "+min(U850_vortex_rm))
;printVarSummary(U850_vortex_rm)
;printVarSummary(U850_vortex_rm(centlat_ind+20:centlat_ind-20,centlon_ind-20:centlon_ind+20))
;printVarSummary(U850_vortex_sub)

U850_vortex_rm(centlat_ind+20:centlat_ind-20,centlon_ind-20:centlon_ind+20)= \
  U850_vortex_rm(centlat_ind+20:centlat_ind-20,centlon_ind-20:centlon_ind+20)-U850_vortex_sub
V850_vortex_rm(centlat_ind+20:centlat_ind-20,centlon_ind-20:centlon_ind+20)= \
  V850_vortex_rm(centlat_ind+20:centlat_ind-20,centlon_ind-20:centlon_ind+20)-V850_vortex_sub
Z850_vortex_rm(centlat_ind+20:centlat_ind-20,centlon_ind-20:centlon_ind+20)= \
  Z850_vortex_rm(centlat_ind+20:centlat_ind-20,centlon_ind-20:centlon_ind+20)-Z850_vortex_sub

MAG_vortex_rm=sqrt(U850_vortex_rm^2+V850_vortex_rm^2)
copy_VarMeta(U850_vortex_rm,MAG_vortex_rm)

;printVarSummary(U850_vortex_rm)

;print(" "+centlat+" "+lat(centlat_ind+28)+" "+lat(centlat_ind-28))
;print(" "+centlon+" "+lon(centlon_ind+28)+" "+lon(centlon_ind-28))

U_comp(case,:,:)=U850_vortex_rm(centlat_ind+80:centlat_ind-80,centlon_ind-80:centlon_ind+80)
V_comp(case,:,:)=V850_vortex_rm(centlat_ind+80:centlat_ind-80,centlon_ind-80:centlon_ind+80)
Z_comp(case,:,:)=Z850_vortex_rm(centlat_ind+80:centlat_ind-80,centlon_ind-80:centlon_ind+80)

wks=gsn_open_wks("png","failure_end_case_"+case)
gsn_define_colormap(wks,cmap)

res=True

res@gsnAddCyclic=False
res@gsnFrame=False
res@gsnDraw=False
res@gsnMaximize=False
res@gsnStringFont=21
res@gsnLeftString="850hPa Wind (kt), Geopotential Height (gpdm)"
res@gsnLeftStringOrthogonalPosF=0.01
res@gsnLeftStringFontHeightF=0.015
res@gsnRightString=name(case)+" @ "+sprinti("%10.0i",yyyymmddhh(case))
;res@gsnRightString="+"+sprinti("%0.2i",counter)+"h"
;res@gsnRightString="+"+sprintf("%4.1f",counter*0.5)+"h"
res@gsnRightStringOrthogonalPosF=0.01
res@gsnRightStringFontHeightF=0.015
res@gsnScalarContour=True

res@vpXF=0.15
res@vpYF=0.95
res@vpHeightF=0.7
res@vpWidthF=0.7

;res@stLineColor=0
;res@stArrowLengthF=0.004
;res@stMinArrowSpacingF=0.004
;res@stMinDistanceF=0.1
;res@stLineThicknessF=2.0
;res@stStepSizeF=0.01

res@mpDataResolution="FinestResolution"
res@mpDataBaseVersion="HighRes"
res@mpLimitMode="LatLon"
;res@mpCenterLatF=centlat
;res@mpCenterLonF=centlon
res@mpMinLatF=centlat-20
res@mpMaxLatF=centlat+20
res@mpMinLonF=centlon-20
res@mpMaxLonF=centlon+20
res@mpMonoFillColor=False
res@mpFillColors=(/-1,-1,-1/)
res@mpOutlineOn=True

res@tmXTOn                = False
res@tmYROn                = False

res@tmXBMode              = "Explicit"
res@tmXBValues            = ispan(100,180,10)
res@tmXBLabels            = (/"100~S~o~N~E","110~S~o~N~","120~S~o~N~E",\
                              "130~S~o~N~","140~S~o~N~E","150~S~o~N~",\
                              "160~S~o~N~E","170~S~o~N~","180~S~o~N~E"/)
res@tmXBMajorLengthF      = 0.01
res@tmXBMajorOutwardLengthF=0.0
res@tmXBMajorThicknessF   = 3.0
;res@tmXBMinorOn           = False
res@tmXBMinorPerMajor     = 4
res@tmXBMinorLengthF      = 0.004
res@tmXBMinorOutwardLengthF=0.0
res@tmXBMinorThicknessF   = 2.0
res@tmXBLabelFont         = 21
res@tmXBLabelFontHeightF  = 0.015
res@tmXBLabelDeltaF       = -0.6

res@tmYLMode              = "Explicit"
res@tmYLValues            = ispan(0,50,10)
res@tmYLLabels            = (/"0~S~o~N~","10~S~o~N~N","20~S~o~N~",\
                              "30~S~o~N~N","40~S~o~N~","50~S~o~N~N"/)
res@tmYLMajorLengthF      = 0.01
res@tmYLMajorOutwardLengthF=0.0
res@tmYLMajorThicknessF   = 3.0
;res@tmYLMinorOn           = False
res@tmYLMinorPerMajor     = 4
res@tmYLMinorLengthF      = 0.004
res@tmYLMinorOutwardLengthF=0.0
res@tmYLMinorThicknessF   = 2.0
res@tmYLLabelFont         = 21
res@tmYLLabelFontHeightF  = 0.015
res@tmYLLabelDeltaF       = -0.3

res@cnFillOn=True
res@cnLevelSelectionMode="ExplicitLevels"
;res@cnLevels:=fspan(0,80,81)
res@cnLevels:=fspan(0,130,66)
res@cnFillOpacityF=1
res@cnLinesOn=False

res@lbBoxSeparatorLinesOn=False
res@lbLabelStride=10

res@pmLabelBarHeightF=0.1

MAG_vortex_rm_kts=MAG_vortex_rm/0.51444

copy_VarMeta(MAG_vortex_rm,MAG_vortex_rm_kts)

plot1=gsn_csm_contour_map(wks,MAG_vortex_rm_kts,res)

res@cnFillOn=False
res@cnLinesOn=True
res@cnInfoLabelOn=False

res@cnLevels:=ispan(floattoint(min(Z850_vortex_rm)),floattoint(max(Z850_vortex_rm)),5)
res@cnLineLabelPlacementMode="constant"
res@cnLineDashSegLenF=0.4
res@cnLineColor="black"
res@cnLineLabelFontColor="black"
res@cnLineLabelFontHeightF=0.010
res@cnLineLabelFontThicknessF=2.0
res@cnLineLabelInterval=1
res@cnLineThicknessF=5.0

plot2=gsn_csm_contour_map(wks,smth9_Wrap(Z850_vortex_rm,0.5,0.25,False),res)

U850_vortex_rm_kts=U850_vortex_rm/0.51444
V850_vortex_rm_kts=V850_vortex_rm/0.51444

copy_VarMeta(U850_vortex_rm,U850_vortex_rm_kts)
copy_VarMeta(V850_vortex_rm,V850_vortex_rm_kts)

res@vcRefMagnitudeF=65
res@vcRefLengthF=0.025
;res@vcGlyphStyle="CurlyVector"
res@vcGlyphStyle="WindBarb"
;res@vcLineArrowThicknessF=3.0
res@vcWindBarbLineThicknessF=2.0
res@vcWindBarbTickLengthF=0.4
res@vcRefAnnoOrthogonalPosF=-0.079
res@vcRefAnnoParallelPosF=1.0
;res@vcMinDistanceF=0.03
res@vcMonoLineArrowColor=True
;res@vcLineArrowColor=1
res@vcRefAnnoArrowUseVecColor=False
res@vcRefAnnoArrowLineColor=1

plot3=gsn_csm_vector_map(wks,U850_vortex_rm_kts(::10,::10),V850_vortex_rm_kts(::10,::10),res)

draw(plot1)
draw(plot2)
draw(plot3)

frame(wks)

end do

rm=systemfunc("rm -rf UVZ_composite_all.nc")

fout=addfile("./UVZ_composite_all.nc","c")
fout->U=U_comp
fout->V=V_comp
fout->Z=Z_comp

end